*start
@layopt layer=message0 visible=false
;呼叫ZOOM~
@call storage=zoom.ks
@bg storage=zoom
@wait time=2000
@layopt layer=message0 visible=true
欢迎来到卡莎的吉里之路-ZOOM篇。[l][r]
这里给大家介绍ZOOM的简单应用。但偶的能力有限，有些我自己还不明白的地方就不在这里介绍了。等以后明白了再来打补丁吧HOHO~[l][r]
首先确定DATA(或Template)文件夹下scenario文件夹内要有ZOOM(或ZOOMROT文件)，呃……【KCDDP】KageXpress的演示版中scenario文件夹内有这些KS文件。(这里建议KAGeXpress3-beta1以后也把这些效果文件？加进去~下雪下雨这类的~)[l][r]
这些确定好后，再来只要有背景图片就好了(图片放哪里，大家都知道吧，其实只要放到DATA(或Template)文件夹下就行吧……)。准备工作就这样了，这里只有关于ZOOM的，其他都略掉哦……[l][r]
顺便在建议用KAGeXpress3-beta1中的WIZARD建立工程~[r]
例如建立工程：D:\卡莎的吉里之路\zoom\[l][r]
现在的背景图片是正常的样子。接下来先看看这个格式，目前图片无变化。[l][r]
还要注意图片尺寸与分辨率一致哦，这里用800*600的比例。[l][cm]
格式：@bgzoom storage=zoom layer=base time=3000 accel=0 sl=0 st=0 sw=800 sh=600 dl=0 dt=0 dw=800 dh=600[l][r]
这里bgzoom 就是开始进行ZOOM移动；[l][r]
storage=zoom(zoom为卡莎这里的图片名称……)；[r]
time=3000 为变化全过程所需时间。[l][r]
accel=0 为变换的速度，值可以为负数，0，正数。下面会详细解释；[l][r]
layer=base设定为背景层。(我一般都忽略了)；[r]
sl=0 为图片初始的左侧坐标，sl=0可以理解为X坐标为0；[l][r]
st=0 为图片初始的高度坐标，st=0可以理解为Y坐标为0；[l][r]
sw=800 为图片初始的宽度，若起始图片需要放大2倍sw=1600；[l][r]
sh=600 为图片初始的高度，如需放大同样sh=1200；[l][r]
这里需要注意的是最好是宽度与高度同时放大同样倍数，否则图片会变形，变长、变短(如果这是你所需要的话就无谓了。)；[l][r]
接下来dl=0 为移动后的图片左侧坐标，移动后X的坐标；[l][r]
dt=0 为移动后的图片高度，移动后的Y坐标；[l][r]
这里都是0，跟sl st没有变化所以图片没有移动变化；[l][r]
dw=800 为图片移动后的宽度，移动后图片缩小2倍 dw=400；[l][r]
dh=600 为图片移动后的高度，移动后缩小图片2倍 dh=300；[l][r]
这里注意同sw sh，宽度与高度的放缩最好倍数相同。[l][r]
还有mode前景层的模式, basestorage，这两个我还不太了解，希望高手这里补充下！[l][r][cm]
接下来开始变化：[l][r]
若图片从最初就在靠右侧的地方无变化，如例只需把sl dl同时确定为200(正数)即可。[l][r]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=0 sl=200 st=0 sw=800 sh=600 dl=200 dt=0 dw=800 dh=600
@wait time=1000
[r]
[r]
@layopt layer=message0 visible=true
图片向左移动，高度大小不变：[l][r]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=0 sl=0 st=0 sw=800 sh=600 dl=-200 dt=0 dw=800 dh=600
@wait time=1000
@layopt layer=message0 visible=true
格式：@bgzoom storage=zoom time=3000 accel=0 sl=0 st=0 sw=800 sh=600 dl=-200 dt=0 dw=800 dh=600[l][r]
如例dl坐标改变，dt高度不变，dl为负数向左移动，负数越小越向左移。[l][r]
[r]
[r]
所以图片向右移动，高度大小不变应该怎么做呢？大家都知道了吧~[l][r]
如果起始的数值不是0。数值变大就会向右移，dl的数值越小越向左。[l][r][cm]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=0 sl=0 st=0 sw=800 sh=600 dl=200 dt=0 dw=800 dh=600
@wait time=1000
@layopt layer=message0 visible=true
再来图片从右往左移动进入：[l][r]
格式：@bgzoom storage=zoom time=3000 accel=0 sl=300 st=0 sw=800 sh=600 dl=-300 dt=0 dw=800 dh=600
起始位置的sl也是这样的，如果图片从左边移动进入，sl=300，dl=-300 即图片从X坐标300移动到-300如背景：[l][r]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=0 sl=300 st=0 sw=800 sh=600 dl=-300 dt=0 dw=800 dh=600
@wait time=1000
[r]
[r]
@layopt layer=message0 visible=true
这里在变化accel大家看看变化：[l][r]
[r]
accel=-4[l][r]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=-4 sl=300 st=0 sw=800 sh=600 dl=-300 dt=0 dw=800 dh=600
@wait time=1000
@layopt layer=message0 visible=true
[r]
accel=-2[l][r]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=-2 sl=300 st=0 sw=800 sh=600 dl=-300 dt=0 dw=800 dh=600
@wait time=1000
@layopt layer=message0 visible=true
[r]
accel=0[l][r]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=0 sl=300 st=0 sw=800 sh=600 dl=-300 dt=0 dw=800 dh=600
@wait time=1000
@layopt layer=message0 visible=true
[r]
accel=2[l][r]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=2 sl=300 st=0 sw=800 sh=600 dl=-300 dt=0 dw=800 dh=600
@wait time=1000
@layopt layer=message0 visible=true
[r]
accel=4[l][r]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=4 sl=300 st=0 sw=800 sh=600 dl=-300 dt=0 dw=800 dh=600
@wait time=1000
@layopt layer=message0 visible=true
[r]
速度的变化accel为负数速度从快到慢；为正数速度从慢到快；0为匀速。[l][r][cm]
@layopt layer=message0 visible=false
@bgzoom storage=zoom time=3000 accel=0 sl=0 st=0 sw=800 sh=600 dl=0 dt=0 dw=800 dh=600
@layopt layer=message0 visible=true
再来是上下的变化。[l][r]
大小不变，往上移动图片，dt为负数，因为图片初始在X,Y(0,0)的位置，图片上移就超出了范围：[l][r]
如例：dt=-200[l][r]
[r]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=0 sl=0 st=0 sw=800 sh=600 dl=0 dt=-200 dw=800 dh=600
@layopt layer=message0 visible=true
同理，往下移动，dt为正数，dt=200。[l][r]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=0 sl=0 st=0 sw=800 sh=600 dl=0 dt=200 dw=800 dh=600
@layopt layer=message0 visible=true
这里需要注意的是，X,Y(0,0)的坐标基准是指设置界面分辨率的大小，如果图片放大或缩小后，移动的坐标会有所不同。[l][r][cm]
基本的介绍的差不多了，现在示范下放大缩小。[l][r]
先来放大。放大的话按照上面介绍的sw sh原本的大小不变，位置不变。[l][r]
图片放大2倍：[l][r]
@layopt layer=message0 visible=false
@bgzoom storage=zoom time=3000 accel=0 sl=0 st=0 sw=800 sh=600 dl=0 dt=0 dw=1600 dh=1200
@wait time=1000
@layopt layer=message0 visible=true
图片缩小2倍：[l][r]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=0 sl=0 st=0 sw=800 sh=600 dl=0 dt=0 dw=400 dh=300
@wait time=1000
@layopt layer=message0 visible=true
若想在图片的某一位置放大显示，就需要结合sl st dl dt这些位置设定了。[l][r]
如例：在卡莎的地方放大2倍的话。[l][r]
格式：@bgzoom storage=zoom time=3000 accel=0 sl=0 st=0 sw=800 sh=600 dl=140 dt=-680 dw=1600 dh=1200[l][r]
第一步，现确定图片放大2倍，dw=1600 dh=1200；[l][r]
第二步，确定位置，卡莎左上侧的坐标是x=70 y=340，此为图片初始[r]
大小时的位置；[l][r]
第三步，因为图片放大显示卡莎需要向右上移动放大图片。[l][r]
按照放大后的图片来说，首先要确定基本的坐标X,Y(0,0)的[r]
位置，否则很容易乱。[l]这里图片放大了2倍，所以卡莎位[r]
置放大2倍的坐标是X,Y(140,680)，dl=140 dt=-680。[l][r][cm]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=0 sl=0 st=0 sw=800 sh=600 dl=140 dt=-680 dw=1600 dh=1200
@wait time=1000
@layopt layer=message0 visible=true
若相反，只需要sl st sw sh与dl dt dw dh数值交换~[l][r]
如：@bgzoom storage=zoom time=3000 accel=0 sl=140 st=-680 sw=1600 sh=12000 dl=0 dt=0 dw=800 dh=600[l][r][cm]
@layopt layer=message0 visible=false
@bg storage=black
@bgzoom storage=zoom time=3000 accel=0 sl=140 st=-680 sw=1600 sh=1200 dl=0 dt=0 dw=800 dh=600
@wait time=1000
@bgzoom storage=zoom time=3000 accel=0 sl=0 st=0 sw=800 sh=600 dl=0 dt=0 dw=800 dh=600
@layopt layer=message0 visible=true
@layopt layer=message0 visible=true
目前来说以上这些应该够用了吧？HOHO~~[l][r]
我总是被坐标弄晕，不过多测试几次，自然就能找到合适的变化位置。[l][r]
至于相似的ZOOMROT.KS因为我还没接触过，所以不太了解，不过都差不多啦~[l][r]
它是图片的旋转，像魔法阵这类的效果~[l][r][cm]
好啦~卡莎的吉里之路-ZOOM篇就到此为止了~[l][r]
如果各位发现有哪些错误，或需补充的地方请一定要告诉我！不足之处请见谅！[l][r]
或者是来
http://krkr.keyfc.net/bbs 发帖子告诉我哦！[l][r]
我们以后再见吧~现在感觉吉里吉里离我们又进了一步\(^o^)[l][r][cm]
@layopt layer=message0 visible=false
@bgzoom storage=wan time=1000 accel=0 sl=0 st=0 sw=800 sh=600 dl=0 dt=0 dw=800 dh=600
