*start
;禁止历史记录
[history output="false"]
;锁定缩略图
[locksnapshot]
;设定右键返回游戏
[rclick enabled="true" jump="true" storage="rmenu.ks" target=*return]
[backlay]
[image layer=3 page="back" storage="主菜单" visible="true" left=0 top=0]
[position layer="message1" page="back" marginl=0 margint=0]
[layopt layer="message1" visible="true" page="back"]
[current layer="message1" page="back"]
[locate x=26 y=135]
[button normal=按钮_存储 target=*save]
[locate x=26 y=185]
[button normal=按钮_读取 target=*load]
[locate x=26 y=235]
[button normal=按钮_设定 target=*option]
[locate x=26 y=285]
[button normal=按钮_历史记录 target=*history]
[locate x=26 y=335]
[button normal=按钮_标题 target=*title]
[locate x=26 y=385]
[button normal=按钮_离开 target=*exit]

[trans method="crossfade" time=200]
[wt]

[s]
;------------------------------------------------------------------------------
*save
[jump storage="save.ks" target=*save]
;------------------------------------------------------------------------------
*load
[jump storage="save.ks" target=*load]
;------------------------------------------------------------------------------
*history
[jump storage="history.ks" target=*start]
;------------------------------------------------------------------------------
*option
[backlay]
[image layer=3 page="back" storage="系统设定" visible="true" left=0 top=0]
[layopt layer="message1" visible="true" page="back"]
[current layer="message1" page="back"]
[er]
[locate x=278 y=193]
[slider value="kag.bgmvolume" base=滑动槽 width=189 height=23 normal=滑动槽按钮]
[locate x=278 y=250]
[slider value="kag.sevolume" base=滑动槽 width=189 height=23 normal=滑动槽按钮]
[locate x=278 y=307]
[slider value="kag.textspeed" base=滑动槽 width=189 height=23 normal=滑动槽按钮 max=10 min=0]
[locate x=455 y=99]
[button normal=按钮_返回 storage="rmenu.ks" target=*return]
[trans method="crossfade" time=200]
[wt]
[s]
;------------------------------------------------------------------------------
*return
[backlay]
[freeimage layer=3 page="back"]
[freeimage layer=4 page="back"]
[freeimage layer=5 page="back"]
[current layer="message1" page="back"]
[er]
[trans method="crossfade" time=200]
[wt]
[current layer="message0" page="fore"]
[rclick enabled="true" call="true" storage="rmenu.ks" target=*start]
;缩略图锁定取消
;这里所有系统(SAVE,LOAD,OPTION)的返回都将返回*return标签，因此锁定取消只要设定一次
;锁定和锁定取消必须是一一对应的，因此如果你设定了多了返回游戏的标签，每个的末尾都要取消锁定
;否则下一次再进入主菜单就会出错
[unlocksnapshot]
[history output="true"]
[return]
;------------------------------------------------------------------------------
*title
[询问窗口 text="确定要返回标题吗？" storage="rmenu.ks" ok="*返回标题" cancel=*cancel]
[s]
*返回标题
[gotostart ask="false"]
;------------------------------------------------------------------------------
*exit
[询问窗口 text="确定要离开游戏吗？" storage="rmenu.ks" ok="*离开游戏" cancel=*cancel]
[s]
*离开游戏
[close ask="false"]
;------------------------------------------------------------------------------
;从询问窗口返回
;------------------------------------------------------------------------------
*cancel
[backlay]
[freeimage layer=6 page="back"]
[current layer="message2" page="back"]
[er]
[trans method="crossfade" time=200]
[wt]
;通过解锁恢复MENU的按钮功能([locklink]在"询问窗口"的宏里)
[unlocklink]
[rclick enabled="true" jump="true" storage="rmenu.ks" target=*return]
[s]